Прерывания в защищенном режиме процессора IA-32 — Архив WASM.RU

Все статьи

Прерывания в защищенном режиме процессора IA-32 — Архив WASM.RU

Вообщем-то на написание этой статьи меня толкнула незавершённость цикла статей http://www.wasm.ru/series.php?sid=20 "Процессор Intel в защищенном режиме". К сожалению, автор не успел рассмотреть детально сам процесс переключения режимов, смены адресации, а так же обработку прерываний, без которой невозможна полноценная работа программы в защищенном режиме. Писать мы будем код для транслятора FASM, сгенерируем чистый бинарный файл и используем его как образ загрузочной дискеты в эмуляторе Bochs или запишем на дискету и загрузим с нее реальный компьютер.

После Power-On-Self-Test процессор генерирует прерывание 19h, обработчик которого управляет дальнейшим ходом загрузки. Он находит первый (в порядке приоритетов, устанавливаемых в BIOS Setup) загрузочный диск, считывает его первый сектор по линейному адресу 07C00 и передает ему управление.

Поскольку процессор при загрузке работает в реальном режиме с 16битной адресацией, нашей задачей будет переключение процессора в защищенный режим с 32битной адресацией, установка обработчиков прерываний и считывание символов с клавиатуры. Так же мы рассмотрим процесс переключения из защищенного режима обратно в реальный.

Итак, сначала некоторые подготовительные действия. Поскольку наше тело загрузят по адресу 7C00 и мы вряд ли уместимся в пределы одного сектора (512 байт), надо обеспечить загрузку всего остального кода с диска. Этот код приведу без дополнительных пояснений, потому что он не совсем в тему нашей статьи:

ORG 0x7C00
use16

start:
    jmp init

....

init:
    ; очистка экрана
    mov  ax,3
    int  10h

    ; иинициализация RM-сегментов и стека
    mov  ax, cs
    mov  ds, ax
    mov  es, ax
    mov  ss, ax
    mov  sp, start
    mov  bp, sp

    ; сие безобразие никак не умещается в пределы одного сектора (512 байт)...
    ; поэтому подгрузим остальные сектора в память
    mov  ah, 2  ; AH = Function                          : Read sectors
    mov  al, 10 ; AL = Number of sectors to read (1-128) : 10 ( с запасом ;-) )
    xor  ch, ch ; CH = Cylinder number (0-1023)          : 0
    mov  cl, 2  ; CL = Sector number (1-17)              : 2
    xor  dx, dx ; DH = Head number (0-15)                : 0
                ; DL = Drive number (0-A:, 1-B:)         : 0 (A:)
    mov  bx, start + 512
    int  13h
    jnc  continue_loading

    ; ошибка чтения. покажем сообщение и грохнем процессор
    jmp display_read_error
read_error db 'R',7, 'e',7, 'a',7, 'd',7, ' ',7, 'e',7, 'r',7, 'r',7, 'o',7, 'r',7
read_err_l dw $-read_error
display_read_error:
    mov  ax, 0B800h
    mov  es, ax
    xor  di, di
    mov  si, read_error
    mov  cx, word [read_err_l]
    rep  movsb
    jmp  $


ends: rb 510-(ends-start)
db 055h, 0aah

    ; чтение успешно, продолжаем иницилизацию
continue_loading:

Теперь в памяти аккуратно распологается весь наш код. Далее нам необходимо включить отключенные (опять же для совместимости) адресные линии, потому что после включения компьютера функционируют только адресные линии A0-A19. Для использования полноценной 32битной адресации нам нужно включить адресную линию A20, установкой бита 1 на порту ввода-вывода 92h:

    ; открываем адресную линию A20
    in   al, 92h
    or   al, 2
    out  92h, al

На время переключения режимов обязательно надо отключить все прерывания, ибо первый же тик таймера свалит нашу систему. Мы отключим не только аппаратные прерывания, но и замаскируем NMI установкой 7-го бита (отсчет веду с нулевого, как всегда; по счету он, конечно, восьмой) в порту 70h:

    ; запрет всех прерываний
    cli
    in   al, 70h
    or   al, 80h
    out  70h, al  ; запрет NMI

Далее нам необходимо построить GDT и IDT. Если с GDT все понятно, то про IDT стоит рассказать подробнее. И в реальном и в защищенном режиме в регистре IDTR процессор хранит адрес и лимит таблицы прерываний.

В реальном режиме база IDTR = 00000h, а лимит - 3FFh (размер 400h байт минус еденица). По адресу 00000 находится так называемая таблица векторов прерываний (Interrupt Vector Table), состоящая из 256 векторов. Каждый вектор содержит смещение и сегмент своего обработчика. Обе компоненты занимают 2 байта, таким образом общий размер таблицы составляет 256*2*2 = 1024 = 400h байт.

В защищенном режиме дело обстоит совершенно по-другому. IDTR должен указывать на так называемую дескрипторную таблицу прерываний (Interrupt Descriptor Table, IDT), состоящую из 8байтных дескрипторов для каждого прерывания, которая может содержать шлюзы задачи, прерывания и ловушки. Мы рассмотрим только шлюз прерывания.

Шлюз прерывания описывается следующей структурой:

Как нетрудно заметить, его формат напоминает дескриптор из GDT/LDT, но есть некоторые изменения. Первое и последнее слова дескриптора шлюза прерывания содержат 32битный адрес обработчика прерывания (зеленое поле "смещение" на картинке). Второе слово содержит селектор сегмента кода, где находится код обработчика. Из дескрипторов сегмента унаследованы только следующие биты:

P (Present) - бит присутствия. Если =1, прерывание обрабатывается, если =0 генерируется исключение общей защиты. DPL (Descriptor Privilege Level) - уровень привилегий, о нем позже. D - разрядность.

При генерации прерывания происходит следующее. Из IDTR извлекается база таблицы дескрипторов прерываний. В этой таблице по номеру прерывания находится дескриптор шлюза прерывания. Если его бит Present сброшен, генерируется исключение общей защиты. Если текущий уровень привилегий отличается от уровня привилегий обработчика, происходит переключение стека и в стеке обработчика сохраняется указатель на стек прерванной задачи (SS и ESP). В стек помещаются регистры EFLAGS, CS, EIP. Для некоторых исключений последним в стек помещается еще и код ошибки, который, кстати, должен вытолкнуть обработчик исключения после обработки. Очищается бит TF, для программного прерывания или исключения сбрасываются биты VM, RF и NT. При вызове обработчика через шлюз прерывания очищается бит IF, блокируя дальнейшие маскируемые аппаратные прерывания.

После обработки прерывания обработчик должен вытолкнуть из стека код ошибки, если он там есть, и выполнить инструкцию IRETD, которая восстанавливает регистр флагов из стека (поле IOPL меняется, если CPL=0, IF меняется, если CPL<=IOPL). Если уровень привилегий прерванной задачи не равен уровню привилегий обработчика, выталкиваются регистры SS и ESP (обратное восстановление стека).

При вызове прерывания действуют механизмы защиты:

- не позволяется передача управления к менее привилегированному коду, если DPL сегмента кода обработчика больше, чем CPL - в отличие от обычной передачи управления, не проверяется поле RPL селектора - поле DPL шлюза прерывания проверяется только при генерации программного прерывания (INT, INT3, INTO). Для исключений и аппаратных прерываний оно игнорируется

Мы создадим таблицу прерываний только из 34 записей. Процессору, грубо говоря, наплевать, что их количество не равно 256. Просто при вызове неопределенных в ней прерываний будет исключение общей защиты. Мы определим обработчики для следующих прерываний:

  • 1 - это у нас будет системный сервис вывода строки на экран =) будет выводить с текущего места ASCIIZ-строку, адрес которой лежит в ESI
  • 13 - обработчик исключения общей защиты #GP. Покажем строчку "** GENERAL PROTECTION FAULT **" на экране
  • 32 - IRQ0 - системный таймер. будем по тику таймера менять буковку на экране (смотрится прикольно ;))
  • 33 - IRQ1 - клавиатура. мы будем отображать символы на экране один за одним, не различая регистр и не воспринимая функциональные клавиши, за одним исключением. Когда будет нажата клавиша <Esc>, мы попробуем переключиться в реальный режим, вызвать прерывание 10h BIOS с кодом AH=3 для очистки экрана и вернуться обратно в защищенный.

Вот такие нехитрые обработчики. Теперь самое время составить таблицу дескрипторов прерываний для нашего загрузчика:

; Interrupt Descriptor Table
IDT:
         dd 0,0 ; 0
         dw syscall_handler, 08h, 1000111000000000b, 0   ; 1
         dd 0,0 ; 2
         dd 0,0 ; 3
         dd 0,0 ; 4
         dd 0,0 ; 5
         dd 0,0 ; 6
         dd 0,0 ; 7
         dd 0,0 ; 8
         dd 0,0 ; 9
         dd 0,0 ; 10
         dd 0,0 ; 11
         dd 0,0 ; 12
         dw exGP_handler, 08h, 1000111000000000b, 0   ; 13  #GP
         dd 0,0 ; 14
         dd 0,0 ; 15
         dd 0,0 ; 16
         dd 0,0 ; 17
         dd 0,0 ; 18
         dd 0,0 ; 19
         dd 0,0 ; 20
         dd 0,0 ; 21
         dd 0,0 ; 22
         dd 0,0 ; 23
         dd 0,0 ; 24
         dd 0,0 ; 25
         dd 0,0 ; 26
         dd 0,0 ; 27
         dd 0,0 ; 28
         dd 0,0 ; 29
         dd 0,0 ; 30
         dd 0,0 ; 31
         dw int8_handler, 08h, 1000111000000000b, 0   ; IRQ 0 - системный таймер
         dw int9_handler, 08h, 1000111000000000b, 0   ; IRQ 1 - клавиатура

    IDT_size     equ $-IDT
    IDTR         dw IDT_size-1
                 dd IDT
    REAL_IDTR    dw 3FFh
                 dd 0

Обращаю внимание на второй IDTR - REAL_IDTR. Он как раз содержит base=0, limit=3ffh, чтобы загрузить его потом при переключении в реальный режим.

Вернемся к загрузке. Мы пока что только разрешили адресную линию A20. Самое время загрузить GDTR и IDTR:

    ; загрузка GDTR
    lgdt fword [GDTR]

    ; загрузка IDTR
    lidt fword [IDTR]

Далее нам необходимо включить защищенный режим установкой младшего бита служебного регистра CR0:

    ; переключение в PM
    mov  eax, cr0
    or   al, 1
    mov  cr0, eax
Что же теперь мы имеем? Процессор уже находится в защищенном режиме, однако код продолжает выполняться в 16битном сегменте (мы ведь помним про так называемые теневые части сегментых регистров. Теневая часть CS все еще хранит 16битный дескриптор сегмента, который нам достался "в наследство" от реального режима).

Самое время перезагрузить дескриптор CS командой дальнего джампа и перейти, наконец, в 32битный режим:

    ; загружаем новый селектор в CS
    jmp  00001000b:PROTECTED_ENTRY

Теперь смело ставим директиву use32 в fasm'е, указывая ему на то, что теперь код выполняется в 32битном режиме и стоит изменить режим генерации префиксов 66 и 67 у опкодов.

Но мы поменяли только регистр CS, в остальные сегментные регистры так и содержат до сих пор старые значения. Пора бы и их переинициализировать селекторами новых сегментов:

use32
PROTECTED_ENTRY:
    ; мы в PM, инициализируем селекторы 32-битных сегментов
    mov  ax, 00010000b  ; DATA
    mov  ds, ax
    mov  ss, ax
    mov  ax, 00011000b  ; VIDEO
    mov  es, ax

Раз мы загрузили нормальный регистр IDTR, мы можем со спокойной совестью, наконец, разрешить аппаратные прерывания и NMI, которые мы запретили на время перехода:

    ; разрешаем аппаратные прерывания и NMI
    in   al, 70h
    and  al, 7Fh
    out  70h, al
    sti

Теперь процессор переведен в полноценный 32битный защищенный режим. Воспользуемся нашим системным сервисом INT 1 и проинформируем об этом пользователя выводом строки "Switched to ProtectedMode. Press to clear display" на экране:

    ; выводим строку
    mov  esi, string
    int 1

...

string   db '  Switched to ProtectedMode. Press  to clear display', 0

Далее ставим положение последующего вывода строк на 160 (третья строчка экрана) и переходим в бесконечный цикл ожидания прерываний:

    ; переходим на 3 строчку
    mov  dword [cursor], 160

    ; бесконечное ожидание прерываний ...
    jmp  $

Теперь рассмотрим наши обработчики. Начнем с простого - системный сервис INT 1:

;
; Системный вызов INT 1 - печать строки
;
; входные параметры: DS:ESI указывает на ASCIIZ-строку
;

syscall_handler:
    pushad
  _puts:
    lodsb
    mov  edi, dword [cursor]
    mov  [es:edi*2], al
    inc  dword [cursor]
    test al, al
    jnz  _puts
    popad
    iretd

Я думаю, ничего пояснять не надо ) Кроме того, что селектор ES у нас по-прежнему должен указывать в сегмент видеобуфера.

Далее обработчик #GP - покажем злостные ругательства и возвратим управление. Стоит заметить, что управление возвращается на ту же инструкцию, которая и вызвала исключение. Не забываем так же вытолкнуть из стека 4х байтный код ошибки.

;
; Обработчик исключения #GP
;

exGP_handler:
    pop  eax ; код ошибки
    mov  esi, gp
    int  1
    iretd
    
gp db '** GENERAL PROTECTION FAULT **',0

Далее мы напишем обработчик IRQ0 от системного таймера. Мы будем инкрементировать байт ES:[0], который является самым первым байтом видеобуфера и будет отображаться в левом верхнем углу экрана:

;
; IRQ 0 обработчик - системный таймер
;

int8_handler:
    inc  byte [es:0] ; увеличим символ в левом верхнем углу экрана
    jmp  int_EOI     ; сбросим заявку на прерывание

Где int_EOI - наш "ничегонеделающий" обработчик, который просто сбрасывает заявку в контроллере прерываний.

Рассмотрим подробнее аппаратные прерывания. В компьютере есть программируемый контроллер прерываний, котогрый тесно взаимосвязан с процессором:

При возникновении аппаратного прерывания инициируется выход #INT контроллера. Он напрямую соединен с входом #INTR процессора. Если флаг IF=0, прерывание отбрасыватеся. Процессор опрашивает вход #INTR после выполнения каждой инструкции. Как только обнаруживается сигнал, процессор сразу же подтверждает прерывание через выход #INTA. Контроллер прерываний принимает сигнал INTA и выставляет на шину данных значние номера прерывания. Процессор считывает номер прерывания и входит в прерывание по описанной выше схеме. Контроллер прерываний 8259A имеет восемь входов IRQ0-IRQ7, открытых для внешних источников, выход INT и вход INTA, соединенные с #INTR и #INTA входом и выходом процессора соответственно. При получении внешнего прерывания на шине данных формируется номер прерывания из суммы IRQ-номера входа и некоторого базового значения, которое обычно равно восьми, а в защищенном режиме придется базу сдвинуть до 20h, как именно - смотри ниже. Таким образом, при получении сигнала на входе IRQ0 генерируется прерывания 8 (у нас будет 32), IRQ1 - 9 (33) и так далее.

При поступлении нескольких заявок от разных источников они обрабатываются по порядку начиная с меньшего номера IRQ. Можно также выборочно заблокировать некоторые заявки от отдельных IRQ-входов. Блокировку, или маскирование заявок, а так же выбор заявки с наибольним приоритетом обеспечивают три байтовых регистра контроллера - interrupt Mask register (iMr), interrupt Request register (iRr), interrupt Service register (iSr) и арбитр приоритетов Page Resolver (PR).

Каждый вход IRQ блокируется отдельным битом регистра масок iMr. Если прерывания на входе IRQn разрешены, бит n регистра iMr сброшен. Регистр маски iMr подключен к порту 21h процессора.

Пусть поступление запросов на вход IRQn разрешено - бит n регистра iMr сброшен. Бит n регистра запросов на прерывание iRr установится, когда придет сигнал на вход IRQn. Арбитр приоритетов PR по значению регистра iSr принимает решение о возможности обслуживания запроса. Заявка может быть принята к обслуживанию, если в регистре iSr не зафиксировано заявок с равным или большим номером. Если все нормально, контроллер выставляет сигнал INT. Заявка принимается к обслуживанию при получении сигнала INTA от процессора, на шину данных выставляется номер прерывания, бит n регистра iRr сбрасывается, бит n регистра iSr устанавливается. Установленный бит n регистра iSr теперь блокирует прерывания от входов с номерами большими либо равными n. Блокировку необходимо снять вручную в процедуре обсдуживания прерывания сбросом бита x в регистре iSr, который подключен к порту 20h (нужно записать значение 3Nh, где N - номер входа). На практике обычно пользуются командой неопределенного сброса, реализуемой посылкой в порт 20h значения 20h. По этой команде в iSr сбрасывается заявка с наименьшим номером - которая обслуживается в данный момент как наиболее приоритетная.

8 входов слишком мало, поэтому чаще всего используются два контроллера прерываний 8259A - так называемые ведомый контроллер, выход INT которого подключен к входу IRQ2 ведущего контроллера, который уже в свою очередь общается с процессором. Это называется каскадным включением контроллеров прерываний. Регистр iMr ведомого контроллера доступен через порт 0a1h, а регистр iSr - через 0a0h.

Теперь стало ясно, как должен выглядеть минимальный обработчик внешних IRQ прерываний - посылка неопределенного сброса контроллеру прерываний обоим контроллерам:

;
; Пустой обработчик. сбрасывает заявку в контроллере
;

int_EOI:
    ; сброс заявки в контроллере прерываний: посылка End-Of-Interrupt (EOI) ...
    push ax
    mov  al, 20h
    out  020h, al   ; ... в ведущий (Master) контроллер ...
    out  0a0h, al   ; ... и в ведомый (Slave) контроллер.
    pop  ax
    iretd           ; возврат из прерывания

Теперь рассмотрим обработчик прерывания IRQ1 от клавиатуры. Прерывание IRQ1 генерируется контроллером клавиатуры каждый раз при нажатии клавиши. Обработчику клавиатуры скан-код считанной клавиши доступен для чтения через порт 060h. Скан-код нужно преобразовать в соответствующий ему ASCII-код символа (если он печатаем) и отобразить на экране. Преобразование произведем по следующей таблице:

; Таблица преобразования печатаемых скан-кодов в ASCII
ascii    db 0,'1234567890-+',0,0,'QWERTYUIOP[]',0,0,'ASDFGHJKL;',"'`",0,0,'ZXCVBNM,./',\
            0,'*',0,' ',0, 0,0,0,0,0,0,0,0,0,0, 0,0, '789-456+1230.', 0,0

Эта таблица содержит символы, индексы которых в таблице соответствуют их сканкодам, либо нули, если символы непечатаемые. Поскольку нажатие клавиш Shift и Caps Lock мы не обрабатываем, поэтому регистр букв у нас различаться не будет. В нашем обработчике нам нужно проверить, нажата ли клавиша (Её скан-код равен еденице). Если это действительно так, то вызовем процедуру переключения в реальный режим и генерации там прерывания 10h для очистки экрана. Если это не так, отобразим символ на экране. В любом случае нужно перед сбросом заявки на прерывание в контроллере прерываний послать подтверздение обработки прерывания контроллеру клавиатуры в порт 061h - необходимо установить и сразу сбросить 7 бит этого порта. После чего необходимо сбросить заявку на прерывание и вернуть управление:

;
; IRQ 1 обработчик - клавиатура
;

int9_handler:
    push ax
    push edi
    xor  ax, ax

    ; запрашиваем позиционный код клавиши
    in   al, 060h

    dec  al   ; Нажат ли  ? (его сканкод = 1)
    jnz _continue_handling

    ; Esc нажат - пробуем переключиться в реальный режим, вызвать там
    ; прерывание 10h с кодом AH=3 (очистка экрана) и вернуться обратно

    mov  ax, 3
    push 10h
    call REAL_MODE_SWITCH_SERVICE

    jmp Ack

_continue_handling:
    ; отжатия не обрабатываем, только нажатия
    mov  ah, al
    and  ah, 80h
    jnz clear_request

    ; преобразуем позиционный код в ASCII по таблице
    and  al, 7Fh
    push edi
    mov  edi, ascii
    add  di, ax
    mov  al, [edi]
    pop  edi

    ; выводим символы на экран один за другим
    mov  edi, dword [cursor]
    shl  edi, 1
    mov  byte [es:edi], al
    inc  dword [cursor]

    ; посылка подтверждения обрабоки в порт клавиатуры
    ; (установка и сброс 7 бита порта 061h)
   Ack:
    in   al, 061h
    or   al, 80
    out  061h, al
    xor  al, 80
    out  061h, al

clear_request:
    pop  edi
    pop  ax
    jmp  int_EOI

Нам осталось определить функцию REAL_MODE_SWITCH_SERVICE, которой в стеке нужно передать номер прерывания и которая будет делать следующее:

  • полноценный переход в 16битный реальный режим
  • генерация прерывания с заданным номером с сохранением регистров
  • переход обратно в 32битный защищенный режим и возврат управления.

Чтобы не портить контекст перед вызовом прерывания, нам нужно позаботиться о сохранении тех регистров, которые мы собираемся изменять в процессе перехода:

use32
old_ax dw ?
old_cl db ?
REAL_MODE_SWITCH_SERVICE:
    mov  [old_cl], cl
    mov  [old_ax], ax

Далее достаем из стека номер прерывания командой mov cl, [esp+4]. После этого отключаем аппаратные прерывания и NMI уже известным нам способом, предварительно запомнив командой pushfd старые флаги. После этого загружаем в IDTR регистр, описывающий таблицу векторов прерываний в реальном режиме:

    ; переключаемся обратно в реальный режим...
    lidt fword [REAL_IDTR]

Теперь нам нужно передать управление в 16битный сегмент с лимитом 64К. Это нужно обязательно сделать перед (!) переключением в реальный режим. Иначе мы получим не реальный режим, а так называемый Unreal Mode, который нас не интересует. Итак, перезагрузка регистра CS новым селектором:

    ; загружаем в CS селектор 16-битного сегмента с лимитом 64к
    jmp  00100000b:__CONT

use16
    __CONT:

Конечно, нужно поставить директиву use16, т.к. дальнейший код выполняется уже в 16битном сегменте. Теперь можно переключиться в реальный режим сбросом бита Protect Enable (PE) в управляющем регистре CR0:

    ; мы в 16битном сегменте. переключаемся в реальный режим.
    mov  eax, cr0
    and  al, 0FEh
    mov  cr0, eax
    jmp  0:REAL_ENTRY

;    Код реального режима
REAL_ENTRY:

Теперь мы находимся в реальном режиме и в теневой части регистра CS находится дескрикптор 16битного малого сегмента. Однако, регистры DS,SS,ES все еще хранят старые значения, для чего их сразу же нужно перезагрузить. Заодно разрешаем аппаратные прерывания и NMI.

REAL_ENTRY:
    mov  ax, cs
    mov  ds, ax
    mov  ss, ax
    mov  es, ax

    ; разрешаем аппаратные прерывания и NMI
    in   al, 70h
    and  al, 7Fh
    out  70h, al
    sti

Теперь динамически сформируем команду INT xx, потому что система команд архитектуры IA-32 поддерживает только команду INT с фиксированным номером прерывания. Нам придется сформировать ее динамически: опкод команды INT xx равен CD xx. Перед генерацией прерывания заодно восстановим регистры ax и cl, которые подвергались изменению в процессе переключения:

    mov  [int_no], cl

    mov  ax, [old_ax]
    mov  cl, [old_cl]

    db 0CDh       ; INT xx
    int_no db 0

    mov  [old_ax], ax

После возврата из прерывания запомним возвращенное значение ax, т.к. мы его поменяем в процессе обратного переключения. Далее все по-новой: запрет аппаратных прерываний и NMI, инициализация защищенного режима, прыжок в 32битный сегмент кода, перезагрузка селекторов DS,ES,SS.

Далее восстанавливаем AX, восстановление флагов командой popfd (нельзя тупо сделать sti, что казалось бы более очевидным, потому как перед во время вызова REAL_MODE_SWTICH_SERVICE прерывания отключены!) и делаем RET с выталкиванием четырех байт из стека (номер прерывания):

     mov  ax, [old_ax]

    ; разрешаем аппаратные прерывания и NMI
    in   al, 70h
    and  al, 7Fh
    out  70h, al
    popfd

    ret  4

На этом мы, собственно, закончим наше и так затянувшееся повествование. Исходный код загрузчика и файл конфигурации Bochs (только в нем надо пути сменить на другие к ROM-BIOS) можно найти здесь: http://gr8.cih.ms/uploads/loader.rar

Пока!

(C) Great, 2007

В статье использованы материалы wasm.ru, dims.karelia.ru и книги А.Жуков, А.Авдюхин "Ассемблер", СПб.:"БХВ-Петербург", 2003.

ЗЫ. Как было справедливо замечено, вектора 0..1F заняты исключениями. Поэтому IRQ желательно перенсести, перепрограммировав контроллер следующей подпрограммой:

use32
redirect_IRQ:
; BX = { BL = Начало для IRQ 0..7, BH = начало для IRQ 8..15 }
; DX = Маска прерываний IRQ ( DL - для IRQ 0..7, DH - IRQ 8..15 )

        ; APIC Off
        mov     ecx,1bh
        rdmsr
        or      ah,1000b
        wrmsr

        mov     al,11h
        out     0a0h,al
        out     20h,al

        mov     al,bh
        out     0a1h,al
        mov     al,bl
        out     21h,al

        mov     al,02
        out     0a1h,al
        mov     al,04
        out     21h,al

        mov     al,01
        out     0a1h,al
        out     21h,al

        mov     al,dh
        out     0a1h,al
        mov     al,dl
        out     21h,al

        ; APIC On
        mov     ecx,1bh
        rdmsr
        and     ah,11110111b
        wrmsr

        ret

В код загрузки после инициализации протектед моде но перед включением прерываний придется добавить

    mov  dx, 0FFFFh
    mov  bx, 2820h
    call redirect_IRQ

для переноса IRQ на 20..27 для ведущего и 28..2F для ведомого контроллеров.

Файлы к статье.

2002-2013 (c) wasm.ru